**Потребовалось отслеживать изменения реквизитов справочников, документов (в т.ч. и табличных частях), так как штатный журнал регистрации не даёт достаточной информации. Поскольку внедрять в рабочую конфу какие-то навороченные подсистемы, коих на данном ресурсе и вообще в сети как грязи, не хотелось, решил я сваять небольшую процедуру регистрации изменений в журнале регистрации. Сама идея подобной фичи возникла после прочтения материалов статьи   
Механизм детального отслеживания изменения содержимого документов**[**http://faq1c.gorbunov.ru/node/1**](http://infostart.ru/redirect.php?url=aHR0cDovL2ZhcTFjLmdvcmJ1bm92LnJ1L25vZGUvMQ==) **Что из этого получилось, смотрите ниже.**

Добавить в какой-либо общий модуль функцию и процедуру

// Возвращает значение или структуру с именами и значениями реквизитов произвольного объекта ссылочного типа  
// прочитанные из информационной базы  
//  
// Параметры:  
//  Ссылка - произвольный объект ссылочного типа (справочник, документ, план обмена, ПВХ, задача)  
//  СтруктураРеквизитов - Необязательно. Может содержать значения:  
//                      строка - имя реквизита объекта.  
//                      строка - имена реквизитов, перечисленные через запятую, в формате требований к свойствам структуры.  
//                      структура - структура с именами реквизитов.  
//  
//  
// Возвращаемое значение:  
//  Структура - если СтруктураРеквизитов имеет тип Структура и заполнен - структура с именами и значениями указанных реквизитов  
//  Структура - если СтруктураРеквизитов не указан или не заполнен - структура с именами и значениями всех реквизитов объекта  
//  Произвольный - если СтруктураРеквизитов строкового типа - значение данного реквизита  
//  
Функция ПолучитьРеквизитыОбъекта(Знач Ссылка, Знач СтруктураРеквизитов = Неопределено) Экспорт  
  
    МетаданныеОбъекта = Ссылка.Метаданные();  
    ИмяТаблицы = МетаданныеОбъекта.ПолноеИмя();  
  
    ЭтоСправочник = Справочники.ТипВсеСсылки().СодержитТип(ТипЗнч(Ссылка));  
    ЭтоПланОбмена = ПланыОбмена.ТипВсеСсылки().СодержитТип(ТипЗнч(Ссылка));  
    ЭтоПВХ = ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(ТипЗнч(Ссылка));  
    ЭтоДокумент = Документы.ТипВсеСсылки().СодержитТип(ТипЗнч(Ссылка));  
    ЭтоЗадача = Задачи.ТипВсеСсылки().СодержитТип(ТипЗнч(Ссылка));  
  
    ТекстЗапроса = "ВЫБРАТЬ ";  
  
    //Формируем список реквизитов объекта для запроса  
    Если ТипЗнч(СтруктураРеквизитов) = Тип("Строка") И ЗначениеЗаполнено(СтруктураРеквизитов) Тогда  
  
        ТекстЗапроса = ТекстЗапроса + СокрЛП(СтруктураРеквизитов);  
        //Если передали список реквизитов, инициализируем структуру  
        Если Найти(СтруктураРеквизитов, ",") <> 0 Тогда  
            СтруктураРеквизитов = Новый Структура(СтруктураРеквизитов);  
        КонецЕсли;  
  
    ИначеЕсли ТипЗнч(СтруктураРеквизитов) = Тип("Структура") И СтруктураРеквизитов.Количество() > 0 Тогда  
  
        Для каждого Реквизит Из СтруктураРеквизитов Цикл ТекстЗапроса = ТекстЗапроса + Реквизит.Ключ + ","; КонецЦикла;  
  
        //Отрезаем последнюю запятую  
        ТекстЗапроса = Лев(ТекстЗапроса, СтрДлина(ТекстЗапроса) - 1);  
  
    Иначе  
  
        //Определяем список реквизитов объектов для подстановки в текст запроса  
        СписокРеквизитов = "";  
        Если ЭтоСправочник ИЛИ ЭтоПланОбмена ИЛИ ЭтоПВХ Тогда  
            Если МетаданныеОбъекта.ДлинаКода > 0 Тогда  
                СписокРеквизитов = "Код,";  
            КонецЕсли;  
            Если МетаданныеОбъекта.ДлинаНаименования > 0 Тогда  
                СписокРеквизитов = СписокРеквизитов + "Наименование,";  
            КонецЕсли;  
            Если ЭтоСправочник ИЛИ ЭтоПВХ Тогда  
                Если МетаданныеОбъекта.Иерархический Тогда  
                    СписокРеквизитов = СписокРеквизитов + "Родитель,";  
                КонецЕсли;  
                Если ЭтоСправочник И (МетаданныеОбъекта.Владельцы.Количество() <> 0) Тогда  
                    СписокРеквизитов = СписокРеквизитов + "Владелец,";  
                КонецЕсли;  
            КонецЕсли;  
        ИначеЕсли ЭтоДокумент Тогда  
            Если МетаданныеОбъекта.ДлинаНомера > 0 Тогда  
                СписокРеквизитов = "Номер,";  
            КонецЕсли;  
            СписокРеквизитов =  СписокРеквизитов + "Дата,";  
        ИначеЕсли ЭтоЗадача Тогда  
            Если МетаданныеОбъекта.ДлинаНомера > 0 Тогда  
                СписокРеквизитов = "Номер,";  
            КонецЕсли;  
            СписокРеквизитов =  СписокРеквизитов + "Дата,";  
            Если МетаданныеОбъекта.ДлинаНаименования > 0 Тогда  
                СписокРеквизитов = СписокРеквизитов + "Наименование,";  
            КонецЕсли;  
        КонецЕсли;  
  
        СписокРеквизитов = СписокРеквизитов + "ПометкаУдаления,";  
  
        Для каждого Реквизит Из МетаданныеОбъекта.Реквизиты Цикл СписокРеквизитов = СписокРеквизитов + Реквизит.Имя + ","; КонецЦикла;  
  
        //Отрезаем последнюю запятую  
        СписокРеквизитов = Лев(СписокРеквизитов, СтрДлина(СписокРеквизитов) - 1);  
        СтруктураРеквизитов = Новый Структура(СписокРеквизитов);  
  
        ТекстЗапроса = ТекстЗапроса + СписокРеквизитов;  
  
    КонецЕсли;  
  
    ТекстЗапроса = ТекстЗапроса + "  
        |ИЗ " + ИмяТаблицы + "  
        |ГДЕ Ссылка = &Ссылка";  
  
    Запрос = Новый Запрос;  
    Запрос.Текст = ТекстЗапроса;  
    Запрос.УстановитьПараметр("Ссылка", Ссылка);  
  
    РезультатЗапроса = Запрос.Выполнить();  
    Если НЕ РезультатЗапроса.Пустой() Тогда  
        Выборка = РезультатЗапроса.Выбрать();  
        Если Выборка.Следующий() Тогда  
            Если ТипЗнч(СтруктураРеквизитов) = Тип("Строка") И ЗначениеЗаполнено(СтруктураРеквизитов) Тогда  
                Возврат Выборка[СтруктураРеквизитов];  
            Иначе  
                ЗаполнитьЗначенияСвойств(СтруктураРеквизитов, Выборка);  
                Возврат СтруктураРеквизитов;  
            КонецЕсли;  
        КонецЕсли;  
    КонецЕсли;  
  
    Возврат Неопределено;  
  
КонецФункции //ПолучитьРеквизитыОбъекта()  
  
// Универсальная процедура, регистрирующая изменения реквизитов объекта (справочник, документ, план обмена, ПВХ)  
// в журнале регистрации  
//  
Процедура РегистрацияИзмененийРеквизитовОбъекта(Объект) Экспорт  
    Перем МетаданныеОбъекта;  
  
    Если НЕ Объект.Ссылка.Пустая() Тогда  
  
        МетаданныеОбъекта = Объект.Метаданные();  
  
        СтрокаСобытие = "Данные.ИзменениеРеквизитов." + МетаданныеОбъекта.Имя;  
        ПрежнийОбъект = Объект.Ссылка;  
        РеквизитыПрежнегоОбъекта = ПолучитьРеквизитыОбъекта(ПрежнийОбъект);  
  
        СтрокаСообщениеРеквизит = "Изменён реквизит ";  
        СтрокаСообщениеТабЧасть = "Изменена таб.часть ";  
        СтрокаСообщениеТабЧастьУдалено = "Удалено ";  
        СтрокаСообщениеТабЧастьДобавлено = "Добавлено ";  
  
        Для Каждого Элемент из РеквизитыПрежнегоОбъекта Цикл  
            ПрежнийРеквизитЗначение = Элемент.Значение;  
            НовыйРеквизитЗначение = Объект[Элемент.Ключ];  
            Если ТипЗнч(НовыйРеквизитЗначение) = Тип("Строка") Тогда  
                НовыйРеквизитЗначение = СокрЛП(НовыйРеквизитЗначение);  
            КонецЕсли;  
            Если ТипЗнч(ПрежнийРеквизитЗначение) = Тип("Строка") Тогда  
                ПрежнийРеквизитЗначение = СокрЛП(ПрежнийРеквизитЗначение);  
            КонецЕсли;  
            Если ПрежнийРеквизитЗначение <> НовыйРеквизитЗначение Тогда  
                ЗаписьЖурналаРегистрации(СтрокаСобытие, УровеньЖурналаРегистрации.Предупреждение, МетаданныеОбъекта, ПрежнийОбъект, СтрокаСообщениеРеквизит + Элемент.Ключ + Символы.ВК + "Прежний: " + Строка(ПрежнийРеквизитЗначение) + Символы.ВК + "Новый: " + Строка(НовыйРеквизитЗначение));  
            КонецЕсли;  
        КонецЦикла;  
  
        Если МетаданныеОбъекта.ТабличныеЧасти.Количество() > 0 Тогда  
  
            // Определяем список проверяемых реквизитов табличных частей,  
            // чтобы не забивать журнал регистрации лишними записями.  
            // Для каждой конфигурации определить свой список, либо удалить проверку  
            // Здесь приведён пример для Управления Торговлей.  
            ПроверяемыеРеквизитыТабЧасти = Новый Структура("Номенклатура, ЕдиницаИзмерения, Количество, Цена, Сумма, СтавкаНДС, СерияНоменклатуры, ХарактеристикаНоменклатуры, СерияНоменклатурыНовая, ХарактеристикаНоменклатурыНовая, СерияНоменклатурыСтарая, ХарактеристикаНоменклатурыСтарая, Проект, ЗаказПокупателя, Сделка, ДокументПартии, ДокументРасчетовСКонтрагентом, СуммаВзаиморасчетов, ДоговорКонтрагента, Контрагент, СтатьяДвиженияДенежныхСредств, ПроцентСкидкиНаценки, НаименованиеТовара, ЗаказПоставщику, ДокументПоступления, ДокументОснование, ИсходноеРазмещение, НовоеРазмещение, СуммаТовара, СуммаПлатежа, Размещение, УвеличениеДолгаКонтрагента, УменьшениеДолгаКонтрагента, КоличествоУчет, ДокументРезерва, ТипЦен, Валюта, Пользователь, ВидЗадолженности, ВидОперации");  
  
            //This code is ported from http://www.kb.mista.ru/article.php?id=115  
            Для Каждого МДТЧ ИЗ МетаданныеОбъекта.ТабличныеЧасти Цикл  
                ИмяТЧ = МДТЧ.Имя;  
                ТЧ1 = Объект[ИмяТЧ];  
                ТЧ2 = ПрежнийОбъект[ИмяТЧ];  
                ТЧ1Количество = ТЧ1.Количество();  
                ТЧ2Количество = ТЧ2.Количество();  
                Если ТЧ1Количество <> ТЧ2Количество Тогда  
                    ЗаписьЖурналаРегистрации(СтрокаСобытие, УровеньЖурналаРегистрации.Предупреждение, МетаданныеОбъекта, Объект.Ссылка, СтрокаСообщениеТабЧасть + ИмяТЧ + Символы.ВК + "Прежняя: " + Строка(ТЧ2Количество) + ". Новая: " + Строка(ТЧ1Количество));  
                КонецЕсли;  
                Если ТЧ1Количество = ТЧ2Количество Тогда  
                    СтрокаСообщение = СтрокаСообщениеРеквизит;  
                ИначеЕсли ТЧ2Количество > ТЧ1Количество Тогда  
                    СтрокаСообщение = СтрокаСообщениеТабЧастьУдалено;  
                ИначеЕсли ТЧ2Количество < ТЧ1Количество Тогда  
                    СтрокаСообщение = СтрокаСообщениеТабЧастьДобавлено;  
                КонецЕсли;  
  
                Для Инд = 0 По Макс(ТЧ1Количество - 1, ТЧ2Количество - 1) Цикл  
  
                    Для Каждого МДРТЧ ИЗ МДТЧ.Реквизиты Цикл  
                        Реквизит = МДРТЧ.Имя;  
  
                        // При необходимости проверку можно удалить  
                        Если НЕ ПроверяемыеРеквизитыТабЧасти.Свойство(Реквизит) Тогда  
                            Продолжить;  
                        КонецЕсли;  
  
                        Если Инд >= ТЧ1Количество Тогда  
                            НовыйРеквизитЗначение = Неопределено;  
                        Иначе  
                            НовыйРеквизитЗначение = ТЧ1[Инд][Реквизит];  
                        КонецЕсли;  
                        Если Инд >= ТЧ2Количество Тогда  
                            ПрежнийРеквизитЗначение = Неопределено;  
                        Иначе  
                            ПрежнийРеквизитЗначение = ТЧ2[Инд][Реквизит];  
                        КонецЕсли;  
  
                        Если (ЗначениеЗаполнено(ПрежнийРеквизитЗначение) И ЗначениеЗаполнено(НовыйРеквизитЗначение)) ИЛИ (НЕ ЗначениеЗаполнено(ПрежнийРеквизитЗначение) И ЗначениеЗаполнено(НовыйРеквизитЗначение)) ИЛИ (ЗначениеЗаполнено(ПрежнийРеквизитЗначение) И НЕ ЗначениеЗаполнено(НовыйРеквизитЗначение)) Тогда  
                            Если ТипЗнч(НовыйРеквизитЗначение) = Тип("Строка") Тогда  
                                НовыйРеквизитЗначение = СокрЛП(НовыйРеквизитЗначение);  
                            КонецЕсли;  
                            Если ТипЗнч(ПрежнийРеквизитЗначение) = Тип("Строка") Тогда  
                                ПрежнийРеквизитЗначение = СокрЛП(ПрежнийРеквизитЗначение);  
                            КонецЕсли;  
                            Если НовыйРеквизитЗначение <> ПрежнийРеквизитЗначение Тогда  
                                ЗаписьЖурналаРегистрации(СтрокаСобытие, УровеньЖурналаРегистрации.Предупреждение, МетаданныеОбъекта, Объект.Ссылка, СтрокаСообщение + ИмяТЧ + "." + Реквизит + " в строке " + (Инд + 1) + Символы.ВК + "Прежний: " + Строка(ПрежнийРеквизитЗначение) + Символы.ВК + "Новый: " + Строка(НовыйРеквизитЗначение));  
                            КонецЕсли;  
                        КонецЕсли;  
  
                    КонецЦикла;  
                КонецЦикла;  
            КонецЦикла;  
        КонецЕсли;  
  
    КонецЕсли;  
  
КонецПроцедуры

Создать подписку на событие для документов

Источник = ДокументОбъект

Событие = ПередЗаписью

Назначить обработчик события

Процедура ПередЗаписьюДокументаПередЗаписью(Источник, Отказ, РежимЗаписи, РежимПроведения) Экспорт  
  
    //Изменения будем регистрировать для случаев проведения или отмены проведения,  
    //так как для простой записи контроль не имеет особого смысла  
    Если НЕ Отказ И ((РежимЗаписи = РежимЗаписиДокумента.Проведение) ИЛИ (РежимЗаписи = РежимЗаписиДокумента.ОтменаПроведения)) Тогда  
        РегистрацияИзмененийРеквизитовОбъекта(Источник);  
    КонецЕсли;  
  
КонецПроцедуры

Создать подписку на событие для справочников (ПВХ, планов обменов)

Источник = ПланВидовХарактеристикОбъект, ПланОбменаОбъект, СправочникОбъект

Событие = ПередЗаписью

Назначить обработчик события

//Регистрируем изменения для справочника, плана обмена, ПВХ  
//  
Процедура ПередЗаписьюОбъектаПередЗаписью(Источник, Отказ) Экспорт  
  
    Если НЕ Отказ Тогда  
        РегистрацияИзмененийРеквизитовОбъекта(Источник);  
    КонецЕсли;  
  
КонецПроцедуры